Ranorex code examples

Public Class UsingRepository 
 Implements ITestModule 
 ' Repository object to access UI elements 
 Private repo As MyFirstTestProjectRepository = MyFirstTestProjectRepository.Instance 
 
 ''' <summary> 
 ''' Constructs a new instance. 
 ''' </summary> 
 ' Do not delete - a parameterless constructor is required! 
 Public Sub New() 
 End Sub 
 
 ''' <summary> 
 ''' Performs the playback of actions in this module. 
 ''' </summary> 
 ''' <remarks>You should not call this method directly, instead pass the module 
 ''' instance to the <see cref="TestModuleRunner.Run(ITestModule)"> method 
 ''' that will in turn invoke this method.</see></remarks> 
 Private Sub ITestModule_Run() Implements ITestModule.Run 
 Mouse.DefaultMoveTime = 300 
 Keyboard.DefaultKeyPressTime = 100 
 Delay.SpeedFactor = 1.0 
 ' Using Ranorex.Form adapter represented by 'MyApp' 
 ' 'MyApp' is used as a folder within the repository; 
 ' the 'Self' property returns a Ranorex.Form object 
 
 ' Activates application 
 repo.MyApp.Self.Activate() 
 ' Log 'Active' state 
 Report.Info(repo.MyApp.Self.Active.ToString()) 
 ' Maximize, Minimize and Restore 
 repo.MyApp.Self.Maximize() 
 repo.MyApp.Self.Minimize() 
 repo.MyApp.Self.Restore() 
 ' Closes application 
 repo.MyApp.Self.Close() 
 
 
 ' Using Ranorex.Button adapter represented by ButtonAdd' 
 ' Read and log value of 'Text' attribute 
 Report.Info(repo.MyApp.Buttons.ButtonAdd.Text) 
 
 ' Press button 
 repo.MyApp.Buttons.ButtonAdd.Press() 
 ' Read and log value of 'Enabled' attribute 
 Report.Info(repo.MyApp.Buttons.ButtonAdd.Enabled.ToString()) 
 
 ' Using Ranorex.RadioButton adapter 
 ' represented by 'GenderOption' 
 
 ' Select radio button 
 repo.MyApp.GenderOption.[Select]() 
 ' Accessing listitems of Ranorex.List adapter 
 ' represented by 'CategoryList' 
 Dim listItems As IList(Of Ranorex.ListItem) = repo.MyApp.CategoryList.Items 
 For Each item As Ranorex.ListItem In listItems 
 Report.Info(item.Text & " is member of CategoryList") 
 Next 
 
 ' Using Ranorex.MenuItem to open 'File' menu 
 repo.MyApp.MenuItemFile.[Select]() 
 ' Selecting sub menu item 'Connect' 
 repo.FileMenu.Connect.[Select]() 
 ' Read and log 'Enabled' state of menu item 'Connect' 
 Report.Info(repo.FileMenu.Connect.Enabled.ToString()) 
 End Sub 
End Class

' Use the 'Info' object to check existence of the 
' 'SaveDialog' item; Method 'Exists' uses the timeout 
' specified for the 'SaveDialog' in the repository 
Report.Info("Exists = " & repo.SaveDialog.SelfInfo.Exists().ToString()) 
 
' Use the 'Info' object to check existence of the 
' 'TextOnline' item which uses the following RXPath: 
' statusbar/text[@accessiblename='Online'] 
' This way you can wait with the timeout specified for 
' the item within the repository for the text 'Online' 
Dim statusTextConnected As Boolean = repo.MyApp.TextOnlineInfo.Exists() 
 
' Using 'Info' objects for validation 
' Throws a Ranorex.ValidationException if validation 
' fails. Automatically reports success or failed message 
' to log file 
Validate.Exists(repo.SaveDialog.ButtonOKInfo) 
 
' Validates the existence of the repository item, 
' but does not throw any exception 
Validate.Exists(repo.SaveDialog.ButtonOKInfo, "Check Object '{0}'", False)

' Creating adapter of type 'NativeWindow' using the "...Info" object 
Dim nativeWnd As Ranorex.NativeWindow = repo.MyApp.SelfInfo.CreateAdapter(Of Ranorex.NativeWindow)(False) 
' ... and read value of attribute 'ProcessName' 
Report.Info("Process name of VIP Database: " & nativeWnd.ProcessName) 
 
' Using Control Adapter to access properties and methods of 
' .NET WinForms control 
Dim winFormsControl As Ranorex.Control = repo.MyApp.SelfInfo.CreateAdapter(Of Ranorex.Control)(False) 
' Set background color of VIP application to Color.Black using the 
' exposed property 'BackColor' 
winFormsControl.SetPropertyValue("BackColor", Color.Black) 
 
' Report screenshot after changing the background color 
Report.Screenshot(repo.MyApp.Self) 
' Closes VIP Database by invoking the 'Close' method 
' exposed by the System.Windows.Forms.Form class 
winFormsControl.InvokeMethod("Close")

' Create a list of adapters using the "Info" object 
Dim buttonList As IList(Of Ranorex.Button) = 
 repo.MyApp.EnabledButtonsInfo.CreateAdapters(Of Ranorex.Button)() 
 
' Move the mouse pointer to each button of the list 
' and add a screenshot for each to the report 
For Each button As Ranorex.Button In buttonList 
 button.MoveTo() 
 Report.Screenshot(button) 
Next

' Validate for Existence 
 
' Using 'Info' objects for validation 
' Throws a Ranorex.ValidationException if validation 
' fails. Automatically reports success or failed message 
' to log file 
Validate.Exists(repo.SaveDialog.ButtonOKInfo) 
 
' Validates the existence of the repository item, 
' but does not throw any exception 
Dim exists As Boolean = Validate.Exists(repo.SaveDialog.ButtonOKInfo,"Check Object '{0}'",false) 
 
' Check whether an application form exists using a RanoreXPath 
Validate.Exists("/form[@controlname='formVipApplication']") 
 
' Check whether an application does not exists 
' for the time specified as timeout for the given repository item 
Validate.NotExists(repo.MyApp.SelfInfo) 
 
' Validate 'Enabled' attribute of button 'Delete' 
Validate.Attribute(repo.MyApp.Buttons.ButtonDeleteInfo,"Enabled",false)

Dim cellObject As Ranorex.Cell = Nothing 
' Try to find a cell object 
Dim found As Boolean = False 
found = Host.Local.TryFindSingle(Of Ranorex.Cell)("/form//table/row/cell[3]", 2000, cellObject) 
' If the expressions does not return an object 
' call Validate.Fail and the test case fails 
If Not found Then 
 Validate.Fail("RanoreXPath with no return") 
End If

Dim cellObject As Ranorex.Cell = Nothing 
' Try to find a cell object using two 
' different RanoreXPath expressions 
Dim found As Boolean = Host.Local.TryFindSingle(Of Ranorex.Cell)("/form//table/row/cell[3]", 2000, cellObject) 
found = found OrElse Host.Local.TryFindSingle(Of Ranorex.Cell)("/form//table/row/cell[4]", 2000, cellObject) 
' If none of the expressions returns an object 
' throw new 'ElementNotFoundException' and test case fails 
If Not found Then 
 Throw New Ranorex.ElementNotFoundException("Both RanoreXPath with no return", Nothing) 
Else 
 ' If the value of attribute 'Text' does not equal to the expected value 
 ' throw new 'ValidationException' to break the test case 
 If cellObject.Text = "MyExpectedTextValue" Then 
 Report.Success("User Specific Validation", "Text validation of cell object succeeded") 
 Else 
 Throw New Ranorex.ValidationException("Text validation of cell object succeeded failed") 
 End If 
End If

Private Sub ITestModule_Run() Implements ITestModule.Run 
 Mouse.DefaultMoveTime = 300 
 Keyboard.DefaultKeyPressTime = 100 
 Delay.SpeedFactor = 1.0 
End Sub

' ----------------- Code Block used by Code Module A ----------------- 
 
' Click 'Save' button to open 'SaveDialog' 
repo.MyApp.Buttons.ButtonSave.Click() 
' Read text message shown with 'SaveDialog' 
' and assign it to the variable 'varDialogTextA' bound to a test case parameter 
varDialogTextA = repo.SaveDialog.TextMessage.TextValue 
 
' -------- Code Block used by User Code Action of recording B -------- 
 
' Read value of module variable 'varDialogTextB' in other code module 
' or recording module using a user code action 
Report.Info(varDialogTextB) 
 
' Get the current data context and log 
' the current row index of a data driven run 
Report.Info(TestCase.Current.DataContext.CurrentRowIndex.ToString())

' Create Ranorex.Button adapter using 'FindSingle' method 
' from Host.Local (starting at root node) with absolute RanoreXPath 
' Note: ElementNotFound exception is thrown if item is not found within 
' the specified timeout of 2000 ms. 
Dim addButtonVar1 As Ranorex.Button = Host.Local.FindSingle(Of Ranorex.Button)("/form[@controlname='formVipApplication']/button[@controlname='btAdd']", 2000) 
addButtonVar1.MoveTo() 
 
' Alternatively you can use 'TryFindSingle' method to prevent 
' a test case from failing because of an exception thrown if 
' the element is not found within the specified timeout of 2000 ms 
Dim addButtonVar2 As Ranorex.Button = Nothing 
Dim found As Boolean = Host.Local.TryFindSingle(Of Ranorex.Button)("/form[@controlname='formVipApplication']/button[@controlname='btAdd']", 2000, addButtonVar2) 
' Move mouse pointer to button 
addButtonVar2.MoveTo() 
 
' Request a list of buttons from the VIP Database application 
' and create a screenshot for each button in the report file 
Dim buttonList As IList(Of Ranorex.Button) = Host.Local.Find(Of Ranorex.Button)("/form[@controlname='formVipApplication']/button", 500) 
For Each bt As Ranorex.Button In buttonList 
 Report.Screenshot(bt) 
Next 
 
' Using find methods in combination with existing Ranorex repository items 
Dim btAdd As Ranorex.Button = repo.MyApp.Self.FindSingle(Of Ranorex.Button)("button[@controlname='btAdd']", 2000)

' Create bitmap to search for 
' within application form and 
' click it 
Dim bmp As Bitmap = Ranorex.Imaging.Load("....Green Sea Turtle Small.bmp") 
' Performs a right click on the image found 
' within the application window based 
' on the image location 
myRepo.WinFormsApp.Self.Click(MouseButtons.Right, bmp) 
 
' You can also search for images that are slightly different to the 
' loaded image by specifying the minimum Similarity for a match (95% = 0.95). 
myRepo.WinFormsApp.Self.Click(new Location(bmp, new Imaging.FindOptions(0.95))) 
 
' OR Set the default Similarity value for all following image operations 
Imaging.FindOptions.Default.Similarity = 0.95 
myRepo.WinFormsApp.Self.Click(bmp) 
 
Report.Success("Image displayed successfully")

' Create bitmap 
Dim bmp As Bitmap = Ranorex.Imaging.Load("....Green Sea Turtle Small.bmp") 
' Search for it within the application window 
If Imaging.Contains(myRepo.WinFormsApp.Self,bmp Then 
 Report.Success("Image found within WinForms application") 
End If

Private Sub ITestModule_Run() Implements ITestModule.Run 
 
 ' Create PopupWatcher 
 Dim myPopupWatcher As New PopupWatcher() 
 
 ' Add a Watch using a RanoreXPath and triggering the Method CloseUpdateCheckDialog 
 myPopupWatcher.Watch("/form[@controlname='UpdateCheckForm']/button[@controlname='m_btnClose']", AddressOf CloseUpdateCheckDialog) 
 
 ' Add a Watch using the info object of a button and triggering the Method CloseUpdateCheckDialog 
 ' myPopupWatcher.Watch(repo.UpdateCheckDialog.btCloseInfo, CloseUpdateCheckDialog); 
 
 ' Add a Watch using the info object of the dialog and the info object of the button to click 
 ' myPopupWatcher.WatchAndClick(repo.UpdateCheckDialog.SelfInfo, repo.UpdateCheckDialog.btCloseInfo); 
 
 ' Add a Watch using a repository folder object and the info object of the button to click 
 ' myPopupWatcher.WatchAndClick(repo.UpdateCheckDialog, repo.UpdateCheckDialog.btCloseInfo); 
 
 ' Start PopupWatcher 
 myPopupWatcher.Start() 
 
End Sub 
 
Public Shared Sub CloseUpdateCheckDialog(myInfo As Ranorex.Core.Repository.RepoItemInfo, myElement As Ranorex.Core.Element) 
 myElement.[As](Of Ranorex.Button)().Click() 
End Sub 
 
Public Shared Sub CloseUpdateCheckDialog(myPath As Ranorex.Core.RxPath, myElement As Ranorex.Core.Element) 
 myElement.[As](Of Ranorex.Button)().Click() 
End Sub

Public Sub Validate_ClipboardContentEqual(compareText As String, customLogMessage As String) 
 ' check if content of clipboard is text 
 If System.Windows.Forms.Clipboard.ContainsText() Then 
 ' Get text from clipboard 
 Dim clipboardtext As String = System.Windows.Forms.Clipboard.GetText() 
 
 ' prepare log message if the log-parameter is empty 
 If String.IsNullOrEmpty(clipboardtext) Then 
 customLogMessage = "Comparing content of clipboard with given text: ({0} vs. {1})" 
 
 
 End If 
 
 ' Validate if given text (compareText) is equal to current text in clipboard 
 Ranorex.Validate.AreEqual(clipboardtext, compareText, customLogMessage) 
 Else 
 Throw New Ranorex.RanorexException("There is not text on the clipboard that can be compared") 
 End If 
End Sub

public Sub Validate_TableContentEqual(repoItem As Ranorex.Adapter, filename_ReferenceTableSnapshot As String, customLogMessageOverall As String, customLogMessageDetail As String) 
 
 ' check if snapshot file exists 
 Const fileNotExists As String = "The given file does not exist: {0}" 
 If Not System.IO.File.Exists(filename_ReferenceTableSnapshot) Then 
 Throw New Ranorex.ValidationException(String.Format(fileNotExists, filename_ReferenceTableSnapshot)) 
 End If 
 
 Dim snap As ElementSnapshot = Nothing 
 Try 
 snap = Ranorex.Core.ElementSnapshot.CreateFromFile(filename_ReferenceTableSnapshot) 'ElementSnapshot.CreateFromFile is available starting with Ranorex 5.4.2 
 Catch 
 Throw New Ranorex.ValidationException("Snapshot could not be loaded from file") 
 End Try 
 
 ' restore table from snapshot 
 Dim refTable As Ranorex.Table 
 Try 
 refTable = snap.Element 
 Catch 
 Throw New Ranorex.ValidationException("Table could not be created from snapshot") 
 End Try 
 Dim tableAdapter = repoItem.[As](Of Ranorex.Table)() 
 If tableAdapter Is Nothing Then 
 Throw New Ranorex.ValidationException("Repo-item could not be accessed") 
 End If 
 
 ' check if rowcount is identical 
 If tableAdapter.Rows.Count <> refTable.Rows.Count Then 
 Throw New Ranorex.ValidationException([String].Format("Tables do not have same number of rows ({0} vs. {1})", tableAdapter.Rows.Count, refTable.Rows.Count)) 
 End If 
 
 ' run through table-rows 
 For iRow As Integer = 0 To tableAdapter.Rows.Count - 1 
 Dim cellCountCur As Integer = tableAdapter.Rows(iRow).Cells.Count 
 Dim cellCountRef As Integer = refTable.Rows(iRow).Cells.Count 
 
 ' check if number of cells is identical in current row 
 If cellCountCur <> cellCountRef Then 
 Throw New Ranorex.ValidationException([String].Format("Table-Rows do not have same number of cells ({0} vs. {1})", cellCountCur, cellCountRef)) 
 End If 
 
 ' run through cells in current row 
 For iCol As Integer = 0 To cellCountCur - 1 
 Dim aCurText As String = tableAdapter.Rows(iRow).Cells(iCol).[As](Of Ranorex.Cell)().Text 
 Dim aRefText As String = refTable.Rows(iRow).Cells(iCol).[As](Of Ranorex.Cell)().Text 
 
 Dim validationMessage As String = String.Empty 
 If String.IsNullOrEmpty(customLogMessageDetail) Then 
 validationMessage = [String].Format("Comparing content of cell ({2}/{3}) (found:'{0}', expected: '{1}')", aCurText, aRefText, iRow, iCol) 
 Else 
 validationMessage = customLogMessageDetail 
 End If 
 
 ' validate whether current text and expected text are identical 
 Ranorex.Validate.AreEqual(aCurText, aRefText, validationMessage) 
 Next 
 Next 
 ' Log overall success 
 If String.IsNullOrEmpty(customLogMessageOverall) Then 
 customLogMessageOverall = "Successfully completed content-validation of table with provided snapshot of table (reference)" 
 End If 
 Ranorex.Report.Log(ReportLevel.Success, customLogMessageOverall) 
End Sub

Public Sub Validate_WebTableContentEqual(repoItem As Ranorex.Adapter, filename_ReferenceTableSnapshot As String, customLogMessageOverall As String, customLogMessageDetail As String) 
 ' check if snapshot file exists 
 Ranorex.Validate.IsTrue(System.IO.File.Exists(filename_ReferenceTableSnapshot), String.Format("Checking existence of snapshot file: {0}", filename_ReferenceTableSnapshot)) 
 
 Dim snap As ElementSnapshot 
 Try 
 ' ElementSnapshot.CreateFromFile is available starting with Ranorex 5.4.2 
 snap = Ranorex.Core.ElementSnapshot.CreateFromFile(filename_ReferenceTableSnapshot) 
 Catch 
 Throw New Ranorex.ValidationException("Snapshot could not be loaded from file") 
 End Try 
 
 ' restore table from snapshot 
 Dim refTable As Ranorex.TableTag 
 Try 
 refTable = snap.Element 
 Catch e As Exception 
 Throw New Ranorex.ValidationException("Table could not be created from snapshot.", e) 
 End Try 
 
 Dim tableAdapter As Ranorex.TableTag = repoItem.[As](Of Ranorex.TableTag)() 
 If tableAdapter Is Nothing Then 
 Throw New Ranorex.ValidationException("Repo-item could not be accessed.") 
 End If 
 
 Dim actTableRows As IList(Of TrTag) = tableAdapter.FindDescendants(Of TrTag)() 
 Dim rowCntAct As Integer = actTableRows.Count 
 Dim refTableRows As IList(Of TrTag) = refTable.FindDescendants(Of TrTag)() 
 Dim rowCntRef As Integer = refTableRows.Count 
 
 ' check if rowcount is identical 
 Ranorex.Validate.AreEqual(rowCntAct, rowCntRef, "Comparing number of rows ({0} vs. {1})") 
 
 ' run through table-rows 
 For iRow As Integer = 0 To actTableRows.Count - 1 
 Dim cellsInActRow As IList(Of Ranorex.WebElement) = actTableRows(iRow).FindChildren(Of Ranorex.WebElement)() 
 Dim cellsInRefRow As IList(Of Ranorex.WebElement) = refTableRows(iRow).FindChildren(Of Ranorex.WebElement)() 
 
 ' check if number of cells is identical in current row 
 Ranorex.Validate.AreEqual(cellsInActRow.Count, cellsInRefRow.Count, "Comparing number of cells in current row ({0} vs. {1})") 
 
 ' run through cells in current row 
 For iCol As Integer = 0 To cellsInActRow.Count - 1 
 Dim aCurText As String = New WebElement(cellsInActRow(iCol)).InnerText 
 Dim aRefText As String = New WebElement(cellsInRefRow(iCol)).InnerText 
 
 Dim validationMessage As String = String.Empty 
 If String.IsNullOrEmpty(customLogMessageDetail) Then 
 validationMessage = [String].Format("Comparing content of cell ({2}/{3}) (found:'{0}', expected: '{1}')", aCurText, aRefText, iRow, iCol) 
 Else 
 validationMessage = customLogMessageDetail 
 End If 
 
 ' validate whether current text and expected text are identical 
 Ranorex.Validate.AreEqual(aCurText, aRefText, validationMessage) 
 Next 
 Next 
 
 ' Log overall success 
 If String.IsNullOrEmpty(customLogMessageOverall) Then 
 customLogMessageOverall = "Successfully completed content-validation of web-table with provided snapshot of web-table (reference)" 
 End If 
 Ranorex.Report.Log(ReportLevel.Success, customLogMessageOverall) 
End Sub

Public Sub Validate_FileTextEqual(filePath_Expected As String, filePath_Current As String, customLogMessage As String) 
 ' prepare log messages 
 Const fileNotFoundMessage As String = "File not found for comparison in Validate_FileContentEqual: {0}" 
 Const logMessage As String = "Comparing content of files ({0} vs. {1})" 
 If String.IsNullOrEmpty(customLogMessage) Then 
 customLogMessage = String.Format(logMessage, filePath_Expected, filePath_Current) 
 End If 
 
 ' check if file exists 
 If Not System.IO.File.Exists(filePath_Current) Then 
 Throw New Ranorex.RanorexException(String.Format(fileNotFoundMessage, filePath_Current)) 
 End If 
 
 ' check if referencing file exists 
 If Not System.IO.File.Exists(filePath_Expected) Then 
 Throw New Ranorex.RanorexException(String.Format(fileNotFoundMessage, filePath_Expected)) 
 End If 
 
 ' check if filenames are identical 
 If filePath_Expected.Equals(filePath_Current) Then 
 Ranorex.Validate.IsTrue(True, customLogMessage) 
 Else 
 Dim current As String = System.IO.File.ReadAllText(filePath_Current) 
 Dim expected As String = System.IO.File.ReadAllText(filePath_Expected) 
 ' validate whether expected value equals to current value 
 Ranorex.Validate.AreEqual(current, expected, customLogMessage) 
 End If 
End Sub

Public Sub Validate_FileBinaryContentEqual(filePath_Expected As String, filePath_Current As String, customLogMessage As String) 
 ' prepare log messages 
 Const fileNotFoundMessage As String = "File not found for comparison in Validate_FileContentEqual: {0}" 
 Const logMessage As String = "Comparing content of files ({0} vs. {1})" 
 If String.IsNullOrEmpty(customLogMessage) Then 
 customLogMessage = String.Format(logMessage, filePath_Expected, filePath_Current) 
 End If 
 
 ' check if file exists 
 If Not System.IO.File.Exists(filePath_Current) Then 
 Throw New Ranorex.ValidationException(String.Format(fileNotFoundMessage, filePath_Current)) 
 End If 
 
 ' check if referencing file exists 
 If Not System.IO.File.Exists(filePath_Expected) Then 
 Throw New Ranorex.ValidationException(String.Format(fileNotFoundMessage, filePath_Expected)) 
 End If 
 
 
 ' check if filenames are identical 
 If filePath_Expected.Equals(filePath_Current) Then 
 Ranorex.Validate.IsTrue(True, customLogMessage) 
 Else 
 Using file1 = New System.IO.FileStream(filePath_Current, System.IO.FileMode.Open) 
 Using file2 = New System.IO.FileStream(filePath_Expected, System.IO.FileMode.Open) 
 ' Check whether files are equal 
 Ranorex.Validate.IsTrue(StreamEquals(file1, file2), customLogMessage) 
 End Using 
 End Using 
 End If 
End Sub 
 
' compare file-streams 
Private Shared Function StreamEquals(stream1 As System.IO.Stream, stream2 As System.IO.Stream) As Boolean 
 Const bufferSize As Integer = 2048 
 Dim buffer1 As Byte() = New Byte(bufferSize - 1) {} 
 Dim buffer2 As Byte() = New Byte(bufferSize - 1) {} 
 While True 
 Dim count1 As Integer = stream1.Read(buffer1, 0, bufferSize) 
 Dim count2 As Integer = stream2.Read(buffer2, 0, bufferSize) 
 
 If count1 <> count2 Then 
 Return False 
 End If 
 
 If count1 = 0 Then 
 Return True 
 End If 
 
 For i As Integer = 0 To count1 - 1 
 If buffer1(i) <> buffer2(i) Then 
 Return False 
 End If 
 Next 
 End While 
End Function

Public Sub Validate_DatabaseFieldWithQuery(OLEConnectionString As String, SQLQuery As String, expectedValue As String, customLogMessage As String) 
 
 ' check is connection string is empty 
 If String.IsNullOrEmpty(OLEConnectionString) Then 
 Throw New Ranorex.RanorexException("ConnectionString is empty") 
 End If 
 
 ' check if SQL statement is empty 
 If SQLQuery.Trim().Equals(String.Empty) Then 
 Throw New Ranorex.RanorexException("SQLQuery is empty") 
 End If 
 
 ' establish connection to database 
 Using connection As New System.Data.OleDb.OleDbConnection(OLEConnectionString) 
 connection.Open() 
 
 Dim command As System.Data.OleDb.OleDbCommand = Nothing 
 Dim SQLReader As System.Data.OleDb.OleDbDataReader = Nothing 
 Try 
 ' set SQL statement and execute search 
 command = New System.Data.OleDb.OleDbCommand(SQLQuery, connection) 
 SQLReader = command.ExecuteReader() 
 
 SQLReader.Read() 
 
 ' check if there is a result 
 If SQLReader.FieldCount > 0 Then 
 
 ' retrieve single result from SQL database 
 Dim actualValue = SQLReader.GetString(0) 
 
 ' prepare log message 
 If customLogMessage.Trim().Equals(String.Empty) Then 
 customLogMessage = "Actual value = '{0}', expected value = '{1}' (database query = " & SQLQuery & ")" 
 End If 
 
 ' compare retrieved value with expected value 
 Ranorex.Validate.AreEqual(actualValue, expectedValue, customLogMessage) 
 Else 
 Throw New Ranorex.RanorexException(String.Format("SQL statement did not return any results: {0}", SQLQuery)) 
 End If 
 Finally 
 command.Dispose() 
 SQLReader.Dispose() 
 End Try 
 End Using 
End Sub

Public Sub Validate_DatabaseTableWithQuery(OLEConnectionString As String, SQLQuery As String, referenceCSVTable As String, csvSeparator As String, customLogMessageOverall As String, customLogMessageDetail As String) 
 
 ' check if reference file exists 
 If Not System.IO.File.Exists(referenceCSVTable) Then 
 Throw New Ranorex.RanorexException(String.Format("File does not exist: {0}", referenceCSVTable)) 
 End If 
 
 ' check if connection string is empty 
 If OLEConnectionString.Trim().Equals(String.Empty) Then 
 Throw New Ranorex.RanorexException("ConnectionString is empty") 
 End If 
 
 ' check if SQL statement is empty 
 If SQLQuery.Trim().Equals(String.Empty) Then 
 Throw New Ranorex.RanorexException("SQLQuery is empty") 
 End If 
 
 ' prepare separator for csv file (if not passed in) 
 Dim separator As Char 
 If String.IsNullOrEmpty(csvSeparator) Then 
 separator = ";"C 
 Else 
 separator = csvSeparator(0) 
 End If 
 
 ' establish database connection 
 Using connection As New System.Data.OleDb.OleDbConnection(OLEConnectionString) 
 connection.Open() 
 
 Dim command As System.Data.OleDb.OleDbCommand = Nothing 
 Dim SQLReader As System.Data.OleDb.OleDbDataReader = Nothing 
 Dim CSVReader As System.IO.StreamReader = Nothing 
 
 Try 
 ' set SQL statement and execute search 
 command = New System.Data.OleDb.OleDbCommand(SQLQuery, connection) 
 SQLReader = command.ExecuteReader() 
 
 ' open csv file (reference file) 
 CSVReader = New System.IO.StreamReader(System.IO.File.OpenRead(referenceCSVTable)) 
 
 ' run through every line in file 
 Dim iRow As Integer = 0 
 While (SQLReader.Read()) AndAlso (Not CSVReader.EndOfStream) 
 
 ' read line from csv file 
 Dim line = CSVReader.ReadLine() 
 
 ' split line into array of values 
 Dim values = line.Split(separator) 
 
 ' check if number of values equals (in current row of csv file and in SQL result) 
 If values.Length <> SQLReader.FieldCount Then 
 Throw New Ranorex.RanorexException(String.Format("Number of fields in SQL query and reference-file does not match ({0} vs. {1})", values.Length + 1, SQLReader.FieldCount)) 
 End If 
 
 
 ' run through every field in SQL result 
 For iFields As Integer = 0 To SQLReader.FieldCount - 1 
 
 Dim expectedValue = values(iFields) 
 Dim actualValue = SQLReader(iFields).ToString() 
 
 ' prepare log message 
 Dim validationMessage As String = String.Empty 
 If String.IsNullOrEmpty(customLogMessageDetail) Then 
 validationMessage = [String].Format("Comparing content of cell ({2}/{3}) (found:'{0}', expected: '{1}')", actualValue, expectedValue, iRow, iFields) 
 Else 
 validationMessage = customLogMessageDetail 
 End If 
 ' validate if actual value and expected value are equal 
 
 Ranorex.Validate.AreEqual(actualValue, expectedValue, customLogMessageDetail) 
 Next 
 iRow += 1 
 End While 
 If String.IsNullOrEmpty(customLogMessageOverall) Then 
 customLogMessageOverall = "Successfully validated SQL Table with given SQL-Statement against content of given CSV file" 
 End If 
 ' Log success 
 
 Ranorex.Report.Log(Ranorex.ReportLevel.Success, customLogMessageOverall) 
 Finally 
 command.Dispose() 
 SQLReader.Dispose() 
 CSVReader.Dispose() 
 End Try 
 End Using 
End Sub

' call method to validate xml code 
Validate_XMLResponse(xml, "books/book/@title", "Ranorex Test Automation Guide", "Validating result of web service request ({0} vs. {1})")

Public Sub Validate_XMLResponse(xmlContent As String, node As String, expectedValue As String, customLogMessage As String) 
 Dim actualValue As String = String.Empty 
 
 ' check if xml content is empty 
 If String.IsNullOrEmpty(xmlContent) Then 
 Throw New Ranorex.ValidationException("Parameter 'xmlContent' is empty") 
 End If 
 
 ' check if node (XPath) is empty 
 If String.IsNullOrEmpty(node) Then 
 Throw New Ranorex.ValidationException("Parameter 'node' is empty") 
 End If 
 
 ' check if expected value is empty 
 If String.IsNullOrEmpty(expectedValue) Then 
 Throw New Ranorex.ValidationException("Parameter 'expectedValue' is empty") 
 End If 
 
 Dim document As New System.Xml.XmlDocument() 
 Try 
 ' load XML from text in xml file 
 document.LoadXml(xmlContent) 
 
 'select the node with given argument (XPath) 
 Dim desiredNode As System.Xml.XmlNode = document.SelectSingleNode(node) 
 
 If desiredNode IsNot Nothing Then 
 actualValue = desiredNode.InnerText 
 Else 
 Throw New Ranorex.ValidationException(String.Format("No node found with XPath '{0}'!", node)) 
 
 End If 
 Catch generatedExceptionName As System.Xml.XmlException 
 Throw New Ranorex.ValidationException("Unable to load valid XML string!") 
 End Try 
 
 
 ' prepare log file 
 If String.IsNullOrEmpty(customLogMessage) Then 
 customLogMessage = "Comparing XML response ({0} vs. {1})" 
 End If 
 
 ' validate if expected value and actual value are equal 
 Ranorex.Validate.AreEqual(expectedValue, actualValue, customLogMessage) 
End Sub